Jedna odpowiedź do kilku adresatów

Outlook nie posiada możliwości nadania odpowiedzi jednobrzmiącej do kilku adresatów w jednym obiekcie. Przy pomocy prostego makra można po zaznaczeniu wiadomości (Ctrl+L i Przycisk myszy) uruchomić poniższą procedurę (Alt+F8).

W zależności od potrzeb adresatów można umieścić w polu DO, DW lub UDW. Steruje tym stała „jak”

Option Explicit
Sub Odpowiedz_do_wielu()
'MVP OShon from VBATools.pl
 Dim oNewMail As MailItem, oMail As Object
 Dim NoDupes As New Collection, adresy$, ile As Variant
 Const jak& = 1 'określenie formy nadania, można przypisać do radiobuttonów
 Set oNewMail = CreateItem(olMailItem)

 On Error Resume Next
 For Each oMail In Application.ActiveExplorer.Selection
    NoDupes.Add oMail.SenderEmailAddress, CStr(oMail.SenderEmailAddress)
 Next oMail
 On Error GoTo blad

 For Each ile In NoDupes
    adresy = adresy & ile & "; "
 Next ile
 'Wysyłanie wiadomości w polu DO = 1, DW = 2, UDW = 3
 Select Case jak
    Case 1: oNewMail.To = Left(adresy, Len(adresy) - 2)
    Case 2: oNewMail.CC = Left(adresy, Len(adresy) - 2)
    Case 3: oNewMail.BCC = Left(adresy, Len(adresy) - 2)
 End Select

 oNewMail.Display
koniec:
 Set oNewMail = Nothing
Exit Sub
blad:
 MsgBox "Błąd wykonania procedury ''Odpowiedz do wielu''" & vbCr _
 & "Zaznacz wiadomości przy pomocy klawisza (Ctrl+Lewy klawisz myszki) i ponów operacje.", _
 vbInformation, "Informacja o błędzie. VBATools.pl"
Resume koniec
End Sub

Osadzenie procedury można znaleźć w artykule: Instalacja i uruchamianie makr. Efektywnie jest dla powtarzalnej czynności dodać przycisk na pasku zadań zgodnie z artykułem: Uruchamianie makr przyciskiem na pasku narzędzi, lub dla wersji 2007/10 jako przycisk szybkiego uruchamiania.

Przy częstym użytkowaniu procedury, przy pozostawianiu możliwości wskazania obszaru uzupełnienia pól można wykonać następującą formę, przypisując pod przyciski do wartości stałej „jak” opisanej pow.:

Rys 1. Interfejs wykonany na potrzeby pow. procedury.

© Wszelkie prawa zastrzeżone. Żadna część ani całość tego artykułu nie może być powielana ani publikowana bez zgody autora.